Text 6, 91 rader
Skriven 2004-07-31 08:52:34 av DAVID WILLIAMS (1:250/514)
     Kommentar till en text av JASEN BETTS
Ärende: Spitfire Onboard Radar?
===============================
-> long skinny pythagorean triangles are easily generated. 
 
->  with a odd (and more than 1 if you want useful results) 
->  b=(a^2-1)/2 
->  c=(a^2+1)/2 
 
-> there is be a way to generalise this to handle all pythagorean triangles. 
-> (I have seen it done) 
 
-> Jasen 
  
I managed to figure out the general method: 
  
A = X * Y 
B = (X^2 - Y^2) \ 2 
C = (X^2 + Y^2) \ 2 
  
X and Y have to have the same "parity", i.e. either both odd or both 
even integers. And, of course, X > Y. 
  
So I wrote it into the following version of the program, which is 
lightning fast! The tricky part was making the triples come out in a 
nice order. I managed to make it so A (the shortest side of the 
triangle, or the smallest number in the triple) comes out in order, but 
B (the middle number) is not always in the right order. However, there 
are never more than a few different Bs for each A, so this doesn't 
matter much. 
  
I'm sure this could be streamlined a bit more... 
  
Thanks for the hint. 
  
                           dow 
  
------------------------------------------------------- 
  
' pythagorean triples 
DEFLNG A-Z 
L = 100 ' limiting length of shortest side 
DIM PN(1 TO L), F(1 TO L) 
PL = 0 
N = 2 
DO 
  FOR X = 1 TO PL 
    IF N = PN(X) * (N \ PN(X)) THEN EXIT FOR 
  NEXT 
  IF X > PL THEN 
    PL = X 
    PN(PL) = N 
  END IF 
  N = N + 1 
LOOP UNTIL N > L \ 2 
P = 0 
CLS 
FOR A = 3 TO L 
  FOR D = 1 TO SQR(A) 
    E! = A / D 
    E = E! 
    B = (E * E - D * D) \ 2 
    GOSUB XX 
  NEXT 
  FOR D = 1 TO A \ 2 
    E! = SQR(A + A + D * D) 
    E = E! 
    B = D * E 
    GOSUB XX 
  NEXT 
NEXT 
END 
XX: 
IF E = E! THEN 
 IF B > A THEN 
  IF D MOD 2 = E MOD 2 THEN 
   FOR Y = 1 TO PL 
    IF A = PN(Y) * (A \ PN(Y)) THEN 
     IF B = PN(Y) * (B \ PN(Y)) THEN EXIT FOR 
    END IF 
   NEXT 
   IF Y > PL THEN 
    C = (E * E + D * D) \ 2 
    P = P + 1 
    PRINT P, , A, B, C 
   END IF 
  END IF 
 END IF 
END IF 
RETURN 
  
-------------------------------------------------------- 
--- Platinum Xpress/Win/WINServer v3.0pr5
 * Origin: The Bayman BBS,Toronto, (416)698-6573 - 1:250/514 (1:250/514)